Biodiversity of Illinois 2: Woodland Habitats/Biodiversity of Illinois 2 - Woodland Habitats.iso/mac/casts/PDFxtraBehaviors.cst/00025_Script_PDF_Print

Text File | 2006-07-11 | 3KB | 81 lines

-- Print

Property pEvent, pSprite, pFromPage, pToPage, pPSlevel, pBinaryOK, pShrinkToFit, pSilent, pAlertFlag

on doPrint me
  set err = PDF_Print(sprite pSprite, pFromPage, pToPage, pPSlevel, pBinaryOK, pShrinkToFit, NOT pSilent)
  if PDF_status(sprite pSprite) then alert "PDF Behavior Error"&RETURN&PDF_error(sprite pSprite)
end doPrint

on mouseUp me
  if (pEvent = #mouseUp) then doPrint(me)
end mouseUp

on mouseDown me
  if (pEvent = #mouseDown) then doPrint(me)
end mouseDown

-- standard behavior stuff --
on getPropertyDescriptionList me
  set defaultValues = GetDefaultValues (me)

  set pdfSpriteList = getProp (defaultValues, #spriteList)
  set defSprite     = getProp (defaultValues, #defaultSprite)
  if (defSprite=0) then
    if the ticks - pAlertFlag > 10 then
      alert "Please create a sprite of type PDF first."
    end if
    set pAlertFlag = the ticks -- The ticks when the user clicked "OK"

    exit
  end if
  set p_list = [#pEvent: [ #comment: "Event", #format:#symbol, #range:[#mouseUp, #mouseDown], #default:#mouseUp], #pSprite: [ #comment: "PDF Sprite is in channel:", #format:#symbol, #range:pdfSpriteList, #default:defSprite], #pFromPage: [ #comment: "From page:", #format:#integer, #default:1], #pToPage: [ #comment: "To page:", #format:#integer, #default:9999], #pPSlevel: [ #comment: "Postscript Level:", #format:#symbol, #range:[#1,#2,#3], #default:#3], #pShrinkToFit: [ #comment: "Shrink to fit:", #format:#boolean, #default:FALSE], #pBinaryOK: [ #comment: "Printer accepts binary data:", #format:#boolean, #default:TRUE], #pSilent: [ #comment: "Show Print Options/Progress dialog:", #format:#boolean, #default:FALSE]]
  return p_list
end

on getBehaviorDescription
  return "Instruct PDF sprite to go to a specific page in the current document.  Parameters are: " &RETURN& "- From page" &RETURN& "- To page: pass any large number for Last Page of document" &RETURN& "- Postscript Level: 1, 2 or 3" &RETURN& "- Shrink to fit: shrink printout to fit target page size" &RETURN& "- Binary data: for printers that accept binary postscript" &RETURN& "- Silent: show/hide Print Options (not supported with Acrobat/Windows)" &RETURN& "Free to use and abuse. (c)1999, Integration New Media, Inc."  &RETURN& "Thanks to James Newton for his suggestions"
end

-- utils --
on GetDefaultValues me
  if the currentSpriteNum then
    set spriteList = GetSpriteList (me #PDF)
    if count (spriteList) then
      set defaultSprite = getAt (spriteList, 1)
    else
      set defaultSprite = 0
    end if

    return [#spriteList: spriteList, #defaultSprite: defaultSprite]

  else -- the currentSpriteNum = 0
    -- Director is merely recompiling this script: return dummy values
    return [#spriteList: [1], #defaultSprite: 1]
  end if
end


on GetSpriteList me, memberType
  -- return list of sprites of type memberType in current frame
  global version
  if (char 1 of version = 6) then
    set maxSprite = 120
  else
    set maxSprite = the lastChannel
  end if

  set aList=[]

  repeat with i = 1 to maxSprite
    set spriteMember = the member of sprite i
    -- if (string(m) contains "member 0") then next repeat -- unnecessary
    if (the type of spriteMember = memberType) then -- (JN) Line break
      append (aList, i)
    end if
  end repeat

  return aList
end GetSpriteList